Part of the fundamental magic of Automation, is its inherent ability to express the data contained in one application, in a different way in another application. What would normally be an intricate laborious process when done by hand, is reduced to a quick effortless operation through AppleScript’s ability to control and link the targeted applications.

The following example script demonstrates these concepts perfectly as it builds a Keynote document from an OmniOutliner outline document.

NOTE: OmniOutliner is productivity software from the Omni Group, and is available for purchase from the Mac App Store, or as a trial version from the Omni Group website.

To try the demo, follow these steps:

DO THIS ►DOWNLOAD and open the OmniOutliner example document.

DO THIS ►If it isn’t already activated, turn on the system-wide Script Menu and create a OmniOutliner scripts folder (details here)

DO THIS ►Open the example script  (⬇ see below )  in the AppleScript Editor, and save the script into the OmniOutliner scripts folder.

DO THIS ►With the example document open in OmniOutliner, select the saved script from the Script Menu.

The script will create a new Keynote document and add a slide, with transitions, for each of the outline sections, filling in titles and body content as indicated. Once the document is created, the presentation will be played from the beginning, and auto-advanced throughout.

New Presentation from Outline
Open in Script Editor
01		property defaultTransitionDuration : 0.5
02		property defaultTransitionDelay : 2.0
03		property defaultAutomaticTransition : true
04
05		tell application "OmniOutliner"
06		activate
07
08		set dialogParagraphBreak to return & return
09		display dialog "This script will create a new Keynote document based on the content of the frontmost OmniOutliner document." & dialogParagraphBreak & "Each section head of the OmniOutliner document will be used as the title for a new slide in the Keynote document." & dialogParagraphBreak & "If a section contains no children, the “Title - Center” master will be used." & dialogParagraphBreak & "If a section contains one child, the “Title & Subtitle” master will be used, with the name of the child becoming the subtitle." & dialogParagraphBreak & "If a section contains more than one child, the “Title & Bullets” master will be used, and the section’s children will become the bullet points for the created slide." & dialogParagraphBreak & "The new slideshow will automatically play from the beginning and auto-advance." with icon 1
10
11		if not (exists document 1) then error number -128
12
13		tell front document
14		set the slideCount to the count of sections
15		end tell
16		end tell
17
18		tell application "Keynote"
19		activate
20
21		set the themeNames to the name of every theme
22
23		set the chosenTheme to ¬
24		(choose from list themeNames with prompt ¬
25		"Choose a theme to use:" default items (item 1 of themeNames))
26
27		if chosenTheme is false then error number -128
28
29		set dialogMessage to "Standard Size or Widescreen?"
30		display dialog dialogMessage buttons {"Cancel", "Standard", "Widescreen"} default button 3
31		if the button returned of the result is "Standard" then
32		set targetWidth to 1024 -- 1440 <-- higher resolution
33		set targetHeight to 768 -- 1080 <-- higher resolution
34		else
35		set targetWidth to 1920
36		set targetHeight to 1080
37		end if
38
39		set thisDocument to ¬
40		make new document with properties ¬
41		{document theme:theme (chosenTheme as string), width:targetWidth, height:targetHeight}
42		end tell
43
44		tell application "OmniOutliner"
45		tell front document
46		repeat with i from 1 to the count of sections
47		tell section i
48		set thisSectionText to name of it
49		repeat with q from 1 to the count of children
50		tell child q
51		set thisSectionText to thisSectionText & return & name of it
52		set the childCount to the count of children
53		if the childCount is not 0 then
54		-- 2nd-level bullets
55		repeat with z from 1 to the childCount
56		set thisSectionText to thisSectionText & return & tab & name of child z
57		end repeat
58		end if
59		end tell
60		end repeat
61		end tell
62		set the paragraphCount to the count of paragraphs of thisSectionText
63		if paragraphCount is 1 then
64		set the masterSlideName to "Title - Center"
65		set thisSlideTitle to thisSectionText
66		set thisSlideBody to ""
67		else if paragraphCount is 2 then
68		set the masterSlideName to "Title & Subtitle"
69		set thisSlideTitle to the first paragraph of thisSectionText
70		set thisSlideBody to the second paragraph of thisSectionText
71		else if paragraphCount is greater than or equal to 3 then
72		set the masterSlideName to "Title & Bullets"
73		set thisSlideTitle to the first paragraph of thisSectionText
74		set thisSlideBodyElements to paragraphs 2 thru -1 of thisSectionText
75		set AppleScript's text item delimiters to return
76		set thisSlideBody to thisSlideBodyElements as string
77		set AppleScript's text item delimiters to ""
78		end if
79		my createSlide(masterSlideName, thisSlideTitle, thisSlideBody)
80		end repeat
81		end tell
82		end tell
83
84		tell application "Keynote"
85		activate
86
87		tell thisDocument to delete slide 1
88
89		start thisDocument from first slide of thisDocument
90		end tell
91
92		on createSlide(masterSlideName, thisSlideTitle, thisSlideBody)
93		try
94		tell application "Keynote"
95		tell front document
96		set thisSlide to make new slide with properties {base slide:master slide masterSlideName}
97		tell thisSlide
98		set the transition properties to ¬
99		{transition effect:dissolve, transition duration:defaultTransitionDuration, transition delay:defaultTransitionDelay, automatic transition:defaultAutomaticTransition}
100		if title showing is true then
101		set the object text of the default title item to thisSlideTitle
102		end if
103		if body showing is true then
104		set the object text of the default body item to thisSlideBody
105		end if
106		end tell
107		end tell
108		end tell
109		return true
110		on error
111		return false
112		end try
113		end createSlide