AppleScript and Keynote: Generate QR Code Image

Generate QR Code Image

This handy script uses AppleScriptObjective-C to create a QR code image based upon the text contained on the clipboard, and imports the created image onto the current slide. It’s a very useful tool for those that often display URLs in their presentations.

NOTE: The following script is written using AppleScriptObj-C, an incredibly powerful fusion of the AppleScript and Objective-C languages. To acquire detailed training materials and examples about AppleScriptObj-C visit: macosxautomation.com/applescript/apps

To use this script, simply copy the URL or text to convert into a QR code to the clipboard, and then run the script. A QR code image will be created and added to the current slide.

Add QR Code using Clipboard Text to Current Slide

use framework "Foundation"

use framework "CoreImage"

use framework "AppKit"

use framework "CoreGraphics"

use scripting additions

property targetMinimumDimension : 400

try

tell application "Keynote"

activate

if playing is true then tell the front document to stop

if not (exists document 1) then error number -128

if (clipboard info for «class utf8») is not {} then

set clipboardText to (get the clipboard as «class utf8»)

else

error "There is no text on the clipboard to convert into a QR code image."

end if

end tell

-- derive a file path for the created image file

set theUUID to current application's NSUUID's UUID()'s UUIDString()

set fileManager to current application's NSFileManager's defaultManager()

set theURL to (fileManager's URLsForDirectory:(current application's NSPicturesDirectory) inDomains:(current application's NSUserDomainMask))'s firstObject()

set the targetItemHFSpath to (theURL as string) & (theUUID as string) & ".jpg"

set targetItemPOSIXpath to POSIX path of targetItemHFSpath

set thisImageObject to my createFullSizeQRCodeImageObjectForString(clipboardText)

my writeNSImageObjectToFileAsJPEG(thisImageObject, targetItemPOSIXpath, false)

set the targetFile to targetItemHFSpath as alias

tell application "Keynote"

activate

if not (exists document 1) then

make new document

end if

tell the front document

set documentWidth to the width of it

set documentHeight to the height of it

tell current slide

-- add the image to the slide and size to desired dimension

set thisImage to make new image with properties {file:targetFile, width:targetMinimumDimension, height:targetMinimumDimension}

-- center the added image on the slide

set the position of thisImage to {(documentWidth - targetMinimumDimension) div 2, (documentHeight - targetMinimumDimension) div 2}

end tell

-- Since the image is automatically added to document bundle, move the source image file to trash

set fileManager to current application's NSFileManager's defaultManager()

set thisPOSIXpath to current application's NSString's stringWithString:targetItemPOSIXpath

set resultingURL to missing value

set URLOfItemToTrash to (current application's |NSURL|'s fileURLWithPath:thisPOSIXpath)

(fileManager's trashItemAtURL:URLOfItemToTrash resultingItemURL:resultingURL |error|:(missing value))

say "Done!"

on error errorMessage number errorNumber

if errorNumber is not -128 then

set spokenErrorTitle to "I was unable to complete your request: "

set cfgutil to "/usr/bin/say"

set theTask to (current application's NSTask's launchedTaskWithLaunchPath:cfgutil arguments:{(spokenErrorTitle & errorMessage)})

tell application (POSIX path of (path to frontmost application))

activate

display alert "Unable to Complete Request:" message errorMessage buttons {"Cancel"} default button 1

end tell

theTask's terminate()

end if

end try

on createFullSizeQRCodeImageObjectForString(thisString)

-- returns a full-size NSImage object

set thisString to current application's NSString's stringWithString:thisString

set thisData to thisString's dataUsingEncoding:(current application's NSUTF8StringEncoding)

set anImageFilter to current application's CIFilter's filterWithname:"CIQRCodeGenerator"

anImageFilter's setDefaults()

anImageFilter's setValue:thisData forKey:"inputMessage"

anImageFilter's setValue:"L" forKey:"inputCorrectionLevel"

set baseImage to anImageFilter's outputImage()

set aTransform to current application's CGAffineTransform's CGAffineTransformMakeScale(100.0, 100.0)

set outputImage to baseImage's imageByApplyingTransform:aTransform

set imageRepresentation to current application's NSCIimageRep's imageRepWithCIImage:outputImage

set resultingImageObject to current application's NSImage's alloc()'s initWithSize:(imageRepresentation's |size|())

resultingImageObject's addRepresentation:imageRepresentation

return resultingImageObject

end createFullSizeQRCodeImageObjectForString

on createScaledQRCodeImageObjectForString(thisString, targetWidth, targetHeight)

-- returns a scaled NSImage object

set thisString to current application's NSString's stringWithString:thisString

100

set thisData to thisString's dataUsingEncoding:(current application's NSUTF8StringEncoding)

101

102

set anImageFilter to current application's CIFilter's filterWithname:"CIQRCodeGenerator"

103

anImageFilter's setDefaults()

104

anImageFilter's setValue:thisData forKey:"inputMessage"

105

anImageFilter's setValue:"L" forKey:"inputCorrectionLevel"

106

107

set baseImage to anImageFilter's outputImage()

108

109

set baseImageSize to baseImage's extent()'s |size|()

110

111

set xScale to targetWidth / (baseImageSize's width())

112

set yScale to targetHeight / (baseImageSize's height())

113

114

set aTransform to current application's CGAffineTransform's CGAffineTransformMakeScale(xScale, yScale)

115

116

set outputImage to baseImage's imageByApplyingTransform:aTransform

117

118

set imageRepresentation to current application's NSCIimageRep's imageRepWithCIImage:outputImage

119

120

set resultingImageObject to current application's NSImage's alloc()'s initWithSize:(imageRepresentation's |size|())

121

122

resultingImageObject's addRepresentation:imageRepresentation

123

124

return resultingImageObject

125

end createScaledQRCodeImageObjectForString

126

127

on writeNSImageObjectToFileAsJPEG(thisImageObject, targetImageFilePath, shouldRevealInFinder)

128

-- create JPEG data for the image object

129

set tiffData to thisImageObject's TIFFRepresentation()

130

set imageRep to current application's NSBitmapimageRep's imageRepWithData:tiffData

131

set theProps to current application's NSDictionary's dictionaryWithObject:1.0 forKey:(current application's NSImageCompressionFactor)

132

set imageData to (imageRep's representationUsingType:(current application's NSJPEGFileType) |properties|:theProps)

133

134

-- write the JPEG data to file

135

set theResult to (imageData's writeTofile:targetImageFilePath atomically:true |error|:(missing value)) as boolean

136

if theResult is true then

137

if shouldRevealInFinder is true then

138

set theseURLs to {}

139

set the end of theseURLs to (current application's NSURL's fileURLWithPath:targetImageFilePath)

140

-- reveal items in file viewer

141

tell current application's NSWorkspace to set theWorkspace to sharedWorkspace()

142

tell theWorkspace to activateFileViewerSelectingURLs:theseURLs

143

end if

144

return true

145

else

146

error "There was a problem writing the image object to file."

147

end if

148

end writeNSImageObjectToFileAsJPEG

Add Link to Shared Photos Album to Keynote as a QR Code

Here’s a version of the example script, saved as an Automator system service for Photos, that converts the selected link to a shared album into a QR code placed on the current slide in Keynote.

DOWNLOAD the Automator workflow file and double-click it to install on your computer. Right-click the selected shared link in Photos, and select the service from the contextual menu.

TOP | CONTINUE

DISCLAIMER

THIS WEBSITE IS NOT HOSTED BY APPLE INC.

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. MACOSXAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. MACOSXAUTOMATION.COM provides this only as a convenience to our users. MACOSXAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and MACOSXAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from MACOSXAUTOMATION.COM and that MACOSXAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.

KEYNOTE SCRIPTING

DISCLAIMER