Although Presenter Notes can be used for a variety of purposes, they most often contain the statements intended to be spoken by the presenter. The following scripts demonstrate interesting uses of these written outlines.

DO THIS ►DOWNLOAD the example presentation.

As many who develop presentations for a living will tell you, for a fresh perpective, it is often useful to work on presenter notes away from the presentation itself. The scripts in this segment demonstrate how to retrieve the presenter notes from a presentation and place them into a new document in another application like Pages or OmniOutliner.

Retrieve Presenter Notes from Active Slides to Pages
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		if not (exists document 1) then error number -128
04		tell the front document
05		set thisDocumentName to the name of it
06		set the combinedPresenterNotes to ¬
07		"PRESENTER NOTES FOR: “" & thisDocumentName & "”" & return
08		repeat with i from 1 to the count of slides
09		tell slide i
10		if skipped is false then
11		set the combinedPresenterNotes to ¬
12		combinedPresenterNotes & return & return & ¬
13		"SLIDE " & (i as string) & " • " & presenter notes of it
14		end if
15		end tell
16		end repeat
17		end tell
18		end tell
19
20		tell application "Pages"
21		activate
22		set thisDocument to ¬
23		make new document with properties {document template:template "Blank"}
24		tell thisDocument
25		set body text to combinedPresenterNotes
26		end tell
27		end tell

(⬇ see below ) A new Pages document containing the presenter notes from the frontmost Keynote presentation:

Here’s a similar script except the presenter notes are moved into a new OmniOutliner document:

NOTE: OmniOutliner is productivity software from the Omni Group, and is available for purchase from the Mac App Store, or as a trial version from the Omni Group website.

New Outliner Document with Presenter Notes of Active Slides
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		if playing is true then tell the front document to stop
04		if not (exists document 1) then error number -128
05
06		tell the front document
07		set thesePresenterNotes to ¬
08		the presenter notes of every slide whose skipped is false
09		end tell
10		end tell
11
12		tell application "OmniOutliner"
13		activate
14		set thisDocument to make new document
15		tell thisDocument
16		repeat with i from 1 to the count of thesePresenterNotes
17		set thisPresenterNote to item i of thesePresenterNotes
18		make new row with properties {topic:thisPresenterNote}
19		end repeat
20		end tell
21		end tell

(⬇ see below ) A new OmniOutliner document containing the presenter notes from the frontmost Keynote presentation:

Since OmniOutliner is an application dedicated to editing outline documents, a script can easily move the edited notes back into the originating Keynote presentation:

Transfer OmniOutliner Outline to Presenter Notes
Open in AppleScript Editor
01		tell application "OmniOutliner"
02		activate
03		try
04		if not (exists document 1) then error number 10000
05
06		display dialog "This script will replace the presenter notes of the active slides of the frontmost Keynote presentation, with the contents of this outline." & return & return & "The contents of each row will become the presenter notes of a corresponding Keynote slide." with icon 1
07
08		tell application "Keynote"
09		activate
10		if not (exists document 1) then error number 10001
11
12		tell the front document
13		set the slideCount to the count of (slides whose skipped is false)
14		end tell
15		end tell
16
17		tell the front document
18		set theseOutlinerNotes to the topic of every row
19		end tell
20
21		if the (count of theseOutlinerNotes) is greater than the slideCount then
22		error number 10002
23		else if the (count of theseOutlinerNotes) is less than the slideCount then
24		error number 10003
25		end if
26		on error errorMessage number errorNumber
27		if errorNumber is 10000 then
28		set errorMessage to "No document is open."
29		else if errorNumber is 10001 then
30		set errorMessage to "No presentation is open."
31		else if errorNumber is 10002 then
32		set errorMessage to ¬
33		"There are more rows in this document than there are active slides in the presentation."
34		else if errorNumber is 10003 then
35		set errorMessage to ¬
36		"There are fewer rows in this document than there are active slides in the presentation."
37		end if
38		if errorNumber is not -128 then
39		display alert "PREPARATION ERROR" message errorMessage
40		end if
41		error number -128
42		end try
43		end tell
44
45		tell application "Keynote"
46		activate
47		tell the front document
48		-- get a list of the active slides
49		set theseSlides to (every slide of it whose skipped is false)
50		repeat with i from 1 to the count of theseSlides
51		set thisSlide to item i of theseSlides
52		set the presenter notes of thisSlide to item i of theseOutlinerNotes
53		end repeat
54		end tell
55		display dialog "The transfer of presenter notes has completed." buttons {"OK"} default button 1
56		end tell

Here’s an interesting script that can provide an opportunity for you to sit back and watch and listen to your presentation being presented to you!

This script uses the built-in text-to-speech capabilities of OS X, and the scriptable presentation controls in Keynote, to display each slide and read the slide’s presenter notes aloud. When a slide’s presenter notes have been read, the script will advance to the next slide.

NOTE: This script is designed to work with presentations of a specific design. “Speakable” slides must not contain object builds and must contain presenter notes.

Simple Play and Say
Open in Script Editor
01		property defaultSlideDuraton : 2
02		property pauseBeforeSpeaking : 1.5
03		property stoppingStatement : "[[slnc 1000]] Stopping presentation."
04
05		tell application "Keynote"
06		activate
07		try
08		if not (exists document 1) then error number -128
09
10		if playing is true then stop the front document
11
12		tell document 1
13		set the slideCount to the count of slides
14		start from first slide
15		end tell
16		repeat with i from 1 to the slideCount
17		if playing is false then
18		my speakSlideNotes(stoppingStatement)
19		error number -128
20		end if
21		tell document 1
22		set thisSlidesPresenterNotes to presenter notes of slide i
23		end tell
24		if thisSlidesPresenterNotes is "" then
25		delay defaultSlideDuraton
26		else
27		if pauseBeforeSpeaking is not 0 then
28		delay pauseBeforeSpeaking
29		end if
30		my speakSlideNotes(thisSlidesPresenterNotes)
31		end if
32		if i is slideCount then
33		exit repeat
34		else
35		if playing is false then
36		my speakSlideNotes(stoppingStatement)
37		error number -128
38		end if
39		show next
40		end if
41		end repeat
42
43		tell document 1 to stop
44		on error errorMessage number errorNumber
45		if errorNumber is not -128 then
46		display alert (("ERROR " & errorNumber) as string) message errorMessage
47		end if
48		end try
49		end tell
50
51		on speakSlideNotes(thisSlidesPresenterNotes)
52		say thisSlidesPresenterNotes -- with waiting until completion
53		end speakSlideNotes

Rendering Presenter Notes to Audio

One more example of “spoken presentation notes.” This script will render the presenter notes of a slide to an audio file of the notes being spoken by the text-to-speech frameworks in OS X. The audio file is then imported into the source slide.

Once the script has completed, you can play the presentation and advance the slides to listen to the presentation.

TIP: Using the Export to HTML script, a presentation containing audio clips can be exported to HTML content, and placed on a server to become an online presentation! See for yourself!

Render Presenter Notes to Audio File and Import
Open in AppleScript Editor
01		tell application "Keynote"
02		activate
03		if not (exists document 1) then error number -128
04		tell the front document
05		repeat with i from 1 to the count of slides
06		tell slide i
07		set thisSlideNumber to the slide number
08		set thisSlidesNotes to presenter notes
09		set thisAudioFile to my renderAndEncode(thisSlidesNotes, thisSlideNumber)
10		if thisAudioFile is not false then
11		set thisAudioClip to ¬
12		make new audio clip with properties {file:thisAudioFile}
13		my deleteFile(thisAudioFile)
14		end if
15		set transition properties to {automatic transition:false}
16		end tell
17		end repeat
18		end tell
19		start the front document from the first slide of the front document
20		end tell
21
22		on deleteFile(thisFileHFSAlias)
23		set thisFilePOSIXpath to the POSIX path of thisFileHFSAlias
24		do shell script "rm -f " & (quoted form of thisFilePOSIXPath)
25		end deleteFile
26
27		on renderAndEncode(thisSlidesNotes, thisSlideNumber)
28		if thisSlidesNotes is "" then
29		return false
30		else
31		-- get the path to the temp folder
32		set the temporaryItemsFolder to the POSIX path of (path to temporary items)
33		-- derive unique names for the audio files
34		set thisTempName to (do shell script "uuidgen")
35		set audioAIFFFileName to ¬
36		"SLIDE-" & thisSlideNumber & "-" & thisTempName & ".aiff"
37		set audioMPEGFileName to ¬
38		"SLIDE-" & thisSlideNumber & "-" & thisTempName & ".m4a"
39		-- construct the paths to the files to be created
40		set targetAIFFFilepath to temporaryItemsFolder & audioAIFFFileName
41		set targetMPEGFilepath to temporaryItemsFolder & audioMPEGFileName
42		-- render text to AIFF audio file
43		do shell script "say" & space & "-o" & space & ¬
44		quoted form of targetAIFFFilePath & space & quoted form of thisSlidesNotes
45		-- encode audio file to MPEG
46		do shell script "afconvert -f 'm4af' -d 'aac ' -s 1 " & ¬
47		(quoted form of targetAIFFFilePath) & space & (quoted form of targetMPEGFilePath)
48		-- delete source audio file
49		do shell script "rm -f " & (quoted form of targetAIFFFilePath)
50		-- return reference to encoded audio file
51		return (targetMPEGFilePath as POSIX file as alias)
52		end if
53		end renderAndEncode